INPUT LOADS ..

TITLE LINE-1 *D. Keith Thesis Model*

LINE-2 *June 1997*

LINE-3 *31 story Office Building - Denver*

LINE-4 *Base Occ. / Base Ltg Rates * ..

RUN-PERIOD JAN 1 1993 THRU DEC 31 1993 ..

ABORT ERRORS ..

DIAGNOSTIC WARNINGS ..

$ LOADS-REPORT SUMMARY = (LS-B,LS-C,LS-D,LS-E,LS-F,LS-G,LS-H,

$ LS-I,LS-J)

$ VERIFICATION = (LV-B,LV-D,LV-L)

LOADS-REPORT SUMMARY = (LS-B,LS-C,LS-D,LS-E,LS-F)

VERIFICATION = (LV-B,LV-D,LV-L)

..

$ Located In Denver

BUILDING-LOCATION LATITUDE=39.7 LONGITUDE=105.0

ALTITUDE=5280

TIME-ZONE=7 AZIMUTH=0.0

ATM-MOISTURE = (.36,.32,.40,.53,.76,1.11,

1.21,1.12,.88,.66,.43,.35)

ATM-TURBIDITY = (0.15,0.18,0.21,0.18,0.18,0.19,

0.22,0.16,0.16,0.14,0.13,0.15) ..

$ Materials

RM0 = MATERIAL TH=0.0833 COND = 0.834 DENS = 55 S-H = 0.4 ..

RM1 = MATERIAL RES = 0.1 ..

RM2 = MATERIAL TH=.25 COND = 0.02 DENS = 1.8 S-H 0.29 ..

RM3 = MATERIAL TH = 0.4167 COND = 0.2083 DENS = 80 S-H = 0.2 ..

RM4 = MATERIAL TH = 0.417 COND = 0.033 DENS = 18 S-H = 0.32 ..

WM1 = MATERIAL TH = 0.5 COND = 0.0751 DENS = 30 S-H = 0.2 ..

$ AIR GAP RESISTANCE CHANGES WITH OUTDOOR CONDITIONS ASSUMED AVERAGE

$ OF WINTER AND SUMMER RE ASHRAE

WM2 = MATERIAL RES = 0.855 ..

WM3 = MATERIAL TH = 0.25 COND = 0.024 DENS = 15 S-H = 0.17 ..

WM4 = MATERIAL RES = 0.875 ..

WM5 = MATERIAL TH = 0.0521 COND = 0.0926 DENS = 50 S-H = 0.2 ..

WM6 = MATERIAL RES = 1.12 ..

FM1 = MATERIAL TH = 0.5 COND = 1.0417 DENS = 140 S-H = 0.2 ..

GLT = GLASS-TYPE PANES = 2 $ THERMAL $

GLASS-CONDUCTANCE= 0.54

SHADING-COEF = 0.55

VIS-TRANS=0 ..

GLV = GLASS-TYPE PANES = 2 $ VISIBLE $

GLASS-CONDUCTANCE= 0.0001

SHADING-COEF = 0.0

VIS-TRANS=0.6 ..

RL1 = LAYERS = MATERIAL = (RM0,RM1,RM2,RM3) I-F-R = 0.61 ..

R1 = CONSTRUCTION = LAYERS = RL1 ..

WL1 = LAYERS = MATERIAL = (WM1,WM2,WM3,WM4,WM5) I-F-R = 0.68 ..

W1 = CONSTRUCTION = LAYERS = WL1 ..

FL1 = LAYERS = MATERIAL = (FM1) I-F-R = 0.61 ..

FLOOR1 = CONSTRUCTION = LAYERS = FL1 ..

CL1 = LAYERS = MATERIAL = (RM4) I-F-R = 0.61 ..

CLNG-1 = CONSTRUCTION = LAYERS = CL1 ..

INTL = LAYERS = MATERIAL = (WM6) ..

INTW = CONSTRUCTION = LAYERS = INTL ..

$ OCCUPANCY SCHEDULE

OCC-1=SCHEDULE

THRU DEC 31

(WD) (1,8) (0) (9,16) (1) (17) (.5) (18,24) (0)

(WEH) (1,24) (0) ..

$ EQUIPMENT SCHEDULE

EQU-1=SCHEDULE

THRU DEC 31

(WD) (1,8) (.25) (9,17) (1) (18,24) (.25)

(WEH) (1,24) (.25) ..

$ LIGHTING SCHEDULE

LGHT-1=SCHEDULE

THRU DEC 31

(WD) (1,7) (.05) (8,18) (1) (19,22) (.5) (23,24) (.05)

(WEH) (1,24) (.05) ..

$ INFILTRATION SCHEDULE

INF-1 =SCHEDULE

THRU DEC 31

(WD) (1,8) (1) (9,17) (.17) (18,24) (1)

(WEH) (1,24) (1) ..

$DEFAULTS

SET-DEFAULT FOR SPACE FLOOR-WEIGHT = 0 ..

SET-DEFAULT FOR EXTERIOR-WALL CONSTRUCTION = W1

INSIDE-VIS-REFL = 0.6

GND-REFLECTANCE = 0.1

H=10 ..

SET-DEFAULT FOR WINDOW GLASS-TYPE= GLT

INSIDE-VIS-REFL= 0.05 ..

SET-DEFAULT FOR I-W INSIDE-VIS-REFL= (0.6)

H=9

CONSTRUCTION = INTW ..

SET-DEFAULT FOR U-W INSIDE-VIS-REFL=.7

H=13 ..

$ GENERAL SPACE DEFINITION

CORE-COND =SPACE-CONDITIONS

PEOPLE-SCHEDULE =OCC-1

AREA/PERSON = 200

PEOPLE-HEAT-GAIN =400

LIGHTING-SCHEDULE =LGHT-1

LIGHTING-TYPE =REC-FLUOR-RV

LIGHT-TO-SPACE =.80

LIGHTING-W/SQFT =1.3

EQUIP-SCHEDULE =EQU-1

EQUIPMENT-W/SQFT =2.0

INF-METHOD =AIR-CHANGE

AIR-CHANGES/HR =0.0

INF-SCHEDULE =INF-1

TEMPERATURE =(76) ..

PERIMETER-COND =SPACE-CONDITIONS PEOPLE-SCHEDULE =OCC-1

AREA/PERSON =100

PEOPLE-HEAT-GAIN =400

LIGHTING-SCHEDULE =LGHT-1

LIGHTING-TYPE =REC-FLUOR-RV

LIGHT-TO-SPACE =.80

LIGHTING-W/SQFT =1.3

EQUIP-SCHEDULE =EQU-1

EQUIPMENT-W/SQFT =2.0

INF-METHOD =AIR-CHANGE

AIR-CHANGES/HR =0.3

INF-SCHEDULE =INF-1

TEMPERATURE =(76)

ZONE-FRACTION1 = 1

LIGHT-SET-POINT1=50 $FC

LIGHT-CTRL-TYPE1 = CONTINUOUS

MIN-POWER-FRAC = .2 MIN-LIGHT-FRAC = .2

LIGHT-CTRL-PROB = 1

MAX-GLARE = 100 ..

$ SPECIFIC SPACE DETAILS

$

$ MID FLOORS (TOTAL OF 29 FLOORS)

$

P-M =SPACE ZONE-TYPE=PLENUM AREA=20000

VOLUME=60000 FLOOR-WEIGHT=5

FLOOR-MULTIPLIER=29 ..

WALL-1PS =EXTERIOR-WALL HEIGHT = 3 WIDTH = 100

AZIMUTH = 180 ..

WALL-1PE =EXTERIOR-WALL HEIGHT = 3 WIDTH = 200

AZIMUTH = 90 ..

WALL-1PN =EXTERIOR-WALL HEIGHT = 3 WIDTH = 100

AZIMUTH = 0 ..

WALL-1PW =EXTERIOR-WALL HEIGHT = 3 WIDTH = 200

AZIMUTH = 270 ..

$ CORE SPACE-MID FLOOR-------------------------------

S1-M =SPACE SPACE-CONDITIONS = CORE-COND

AREA = 11900 VOLUME = 107100

FLOOR-MULTIPLIER=29 ..

$ CEILING SURFACE OF CORE

C5-1 =INTERIOR-WALL AREA = 11900 NEXT-TO P-M

CONSTRUCTION = CLNG-1 TILT=0.0 ..

$ FLOOR SURFACE OF CORE

F5-1 =INTERIOR-WALL AREA = 11900

CONSTRUCTION = FLOOR1 TILT=180.0

NEXT-TO P-M ..

$ SOUTH ZONE-------------------------------------

S5-M =SPACE SPACE-CONDITIONS = PERIMETER-COND

AREA = 1275 VOLUME = 11475

FLOOR-MULTIPLIER=29

DAYLIGHTING=NO

LIGHT-REF-POINT1=(38,7,2.5) ..

SOUTH5-M =EXTERIOR-WALL HEIGHT = 9.0 WIDTH = 100

X=0 Y=0 Z=0 AZIMUTH = 180 ..

GL5-M =WINDOW HEIGHT=4.5 WIDTH = 100

..

$ CEILING SURFACE OF SOUTH ZONE

C1-1 =INTERIOR-WALL AREA = 1275 NEXT-TO P-M

CONSTRUCTION = CLNG-1 TILT=0.0 ..

$FLOOR SURFACE OF SOUTH ZONE

FL-M5=INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-M ..

$INTERIOR WALLS OF SOUTH ZONE

S12 =INTERIOR-WALL AREA=630 NEXT-TO S1-M

CONSTRUCTION = INTW ..

S14 =INTERIOR-WALL AREA=191 NEXT-TO S4-M

CONSTRUCTION = INTW ..

S15 =INTERIOR-WALL LIKE S12 NEXT-TO S2-M ..

$DAYLIGHT ROOM---------

SWALL1=I-W X=35 Y=15

WIDTH=15 AZIMUTH=270

I-W-TYPE=ADIABATIC ..

SWALL2=I-W X=50 Y=15

WIDTH=15 AZIMUTH=0

I-W-TYPE=ADIABATIC ..

SWALL3=I-W X=50 Y=0

WIDTH=15 AZIMUTH=90

I-W-TYPE=ADIABATIC ..

SWALL4=E-W X=35 Y=0 Z=3.4

W=15 H=4.6 AZIMUTH=180

..

SWIND=WINDOW G-T=GLV H=4.5 W=15 ..

SFLR=I-W X=35 Y=15

TILT=180 W=15 H=15

INSIDE-VIS-REFL= (0.20)

I-W-TYPE=ADIABATIC ..

SCLG=I-W X=35 Y=0 Z=9

TILT=0 W=15 H=15

I-W-TYPE=ADIABATIC ..

$ NORTH ZONE----------------------------------------------

S3-M =SPACE SPACE-CONDITIONS = PERIMETER-COND

AREA = 1275 VOLUME = 11475

FLOOR-MULTIPLIER= 29

DAYLIGHTING=NO

LIGHT-REF-POINT1=(47,193,2.5) ..

NORTH3-M =EXTERIOR-WALL HEIGHT = 9 WIDTH = 100

X=100 Y=200 Z=0 AZIMUTH = 0.0 ..

GL3-M =WINDOW HEIGHT=4.5 WIDTH = 100 ..

$ CEILING SURFACE OF NORTH ZONE

C3-1 =INTERIOR-WALL AREA = 1275 NEXT-TO P-M

CONSTRUCTION = CLNG-1 TILT=0.0 ..

$FLOOR SURFACE OF NORTH ZONE

FL-M3=INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-M ..

$INTERIOR WALLS OF NORTH ZONE

M31 =INTERIOR-WALL AREA=630 NEXT-TO S1-M

CONSTRUCTION = INTW ..

M34 =INTERIOR-WALL AREA=191 NEXT-TO S4-M

CONSTRUCTION = INTW ..

M32 =INTERIOR-WALL LIKE M34 NEXT-TO S2-M ..

$DAYLIGHT ROOM---------

NWALL1=I-W X=35 Y=200

WIDTH=15 AZIMUTH=270

I-W-TYPE=ADIABATIC ..

NWALL2=I-W X=35 Y=185

WIDTH=15 AZIMUTH=180

I-W-TYPE=ADIABATIC ..

NWALL3=I-W X=50 Y=185

WIDTH=15 AZIMUTH=90

I-W-TYPE=ADIABATIC ..

NWALL4=E-W X=50 Y=200 Z=3.4

W=15 H=4.6 AZIMUTH=0

..

NWIND=WINDOW G-T=GLV H=4.5 W=15 ..

NFLR=I-W X=35 Y=200

TILT=180 W=15 H=15

INSIDE-VIS-REFL= (0.20)

I-W-TYPE=ADIABATIC ..

NCLG=I-W X=35 Y=185 Z=9

TILT=0 W=15 H=15

I-W-TYPE=ADIABATIC ..

$ WEST ZONE---------------------------------------------

S2-M =SPACE SPACE-CONDITIONS = PERIMETER-COND

AREA = 2775 VOLUME = 24975

FLOOR-MULTIPLIER= 29

DAYLIGHTING=NO

LIGHT-REF-POINT1=(7,93,2.5) ..

WEST-M =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=0.0 Y=200 Z=0 AZIMUTH = 270 ..

GL2-M =WINDOW HEIGHT=4.5 WIDTH = 200 ..

$ CEILING SURFACE OF WEST ZONE

C2-1 =INTERIOR-WALL AREA = 2775 NEXT-TO P-M

CONSTRUCTION = CLNG-1 TILT=0.0 ..

$FLOOR SURFACE OF WEST ZONE

FL-M2=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-M ..

$INTERIOR WALLS OF WEST ZONE

M21 =INTERIOR-WALL AREA=1530 NEXT-TO S1-M

CONSTRUCTION = INTW ..

$DAYLIGHT ROOM--------

WWALL1=I-W X=15 Y=100

WIDTH=15 AZIMUTH=0

I-W-TYPE=ADIABATIC ..

WWALL2=I-W X=15 Y=85

WIDTH=15 AZIMUTH=90

I-W-TYPE=ADIABATIC ..

WWALL3=I-W X=0 Y=85

WIDTH=15 AZIMUTH=180

I-W-TYPE=ADIABATIC ..

WWALL4=E-W X=0 Y=100 Z=3.4

W=15 H=4.6 AZIMUTH=270

..

WWIND=WINDOW G-T=GLV H=4.5 W=15 ..

WFLR=I-W X=15 Y=85

TILT=180 W=15 H=15

INSIDE-VIS-REFL= (0.20)

I-W-TYPE=ADIABATIC ..

WCLG=I-W X=0 Y=85 Z=9

TILT=0 W=15 H=15

I-W-TYPE=ADIABATIC ..

$ EAST ZONE-------------------------------------------

S4-M =SPACE SPACE-CONDITIONS = PERIMETER-COND

AREA = 2775 VOLUME = 24975

FLOOR-MULTIPLIER=29

DAYLIGHTING=NO

LIGHT-REF-POINT1=(88,93,2.5) ..

EAST-M =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=100 Y=0.0 Z=0 AZIMUTH = 90 ..

GL4-M =WINDOW HEIGHT=4.5 WIDTH = 200 ..

$ CEILING SURFACE OF EAST ZONE

C4-1 =INTERIOR-WALL AREA = 2775 NEXT-TO P-M

CONSTRUCTION = CLNG-1 TILT=0.0 ..

$FLOOR SURFACE OF EAST ZONE

FL-M4=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-M ..

$INTERIOR WALLS OF EAST ZONE

M41 =INTERIOR-WALL AREA=1530 NEXT-TO S1-M

CONSTRUCTION = INTW ..

$ DAYLIGHT ROOM----------------

EWALL1=I-W X=85 Y=85

WIDTH=15 AZIMUTH=180

I-W-TYPE=ADIABATIC ..

EWALL2=I-W X=85 Y=100

WIDTH=15 AZIMUTH=270

I-W-TYPE=ADIABATIC ..

EWALL3=I-W X=100 Y=100

WIDTH=15 AZIMUTH=0

I-W-TYPE=ADIABATIC ..

EWALL4=E-W X=100 Y=85 Z=3.4

W=15 H=4.6 AZIMUTH=90 ..

EWIND=WINDOW G-T=GLV H=4.5 W=15 ..

EFLR=I-W X=85 Y=100

TILT=180 W=15 H=15

INSIDE-VIS-REFL= (0.20)

I-W-TYPE=ADIABATIC ..

ECLG=I-W X=85 Y=85 Z=9

TILT=0 W=15 H=15

I-W-TYPE=ADIABATIC ..

$-------------------------------------------------------------------

$TOP FLOOR (ONE OF A KIND)

$

$

P-T = SPACE LIKE P-M FLOOR-MULTIPLIER=1 ..

TOP-1 =ROOF HEIGHT=200 WIDTH=100

X=0 Y=0 Z=403 AZIMUTH = 180

TILT=0 GND-REFLECTANCE=0

CONSTRUCTION = R1 ..

$core

S1-T = SPACE LIKE S1-M FLOOR-MULTIPLIER=1 ..

C5-1T =INTERIOR-WALL AREA = 11900 NEXT-TO P-T

CONSTRUCTION = CLNG-1 TILT=0.0 ..

F5-1T =INTERIOR-WALL AREA = 11900

CONSTRUCTION = FLOOR1 TILT=180.0

NEXT-TO P-T ..

$ west---------------------------------------

S2-T = SPACE LIKE S2-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(7,93,2.5) ..

WEST-T =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=0.0 Y=200 Z=0 AZIMUTH = 270 ..

GL2-T =WINDOW HEIGHT=4.5 WIDTH = 200 ..

C2-1T =INTERIOR-WALL AREA = 2775 NEXT-TO P-T

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M2T=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-T ..

M21T =INTERIOR-WALL AREA=1530 NEXT-TO S1-T

CONSTRUCTION = INTW ..

$DAYLIGHT ROOM-------------------

W31WALL1=I-W LIKE WWALL1 ..

W31WALL2=I-W LIKE WWALL2 ..

W31WALL3=I-W LIKE WWALL3 ..

W31WALL4=E-W LIKE WWALL4 ..

W31WIND=WINDOW LIKE WWIND ..

W31FLR=I-W LIKE WFLR ..

W31CLG=I-W LIKE WCLG ..

$north--------------------------------------------

S3-T = SPACE LIKE S3-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(47,193,2.5) ..

NORTH3-T =EXTERIOR-WALL HEIGHT = 9 WIDTH = 100

X=100 Y=200 Z=0 AZIMUTH = 0.0 ..

GL3-T =WINDOW HEIGHT=4.5 WIDTH = 100 ..

M31T =INTERIOR-WALL AREA=630 NEXT-TO S1-T

CONSTRUCTION = INTW ..

M34T =INTERIOR-WALL AREA=191 NEXT-TO S4-T

CONSTRUCTION = INTW ..

M32T =INTERIOR-WALL LIKE M34 NEXT-TO S2-T ..

C3-1T =INTERIOR-WALL AREA = 1275 NEXT-TO P-T

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M3T=INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-T ..

$DAYLIGHT ROOM-----------------------

N31WALL1=I-W LIKE NWALL1 ..

N31WALL2=I-W LIKE NWALL2 ..

N31WALL3=I-W LIKE NWALL3 ..

N31WALL4=E-W LIKE NWALL4 ..

N31WIND=WINDOW LIKE NWIND ..

N31FLR=I-W LIKE NFLR ..

N31CLG=I-W LIKE NCLG ..

$east-----------------------------------------

S4-T = SPACE LIKE S4-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(88,93,2.5) ..

EAST-T =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=100 Y=0.0 Z=0 AZIMUTH = 90 ..

GL4-T =WINDOW HEIGHT=4.5 WIDTH = 200 ..

M41T =INTERIOR-WALL AREA=1530 NEXT-TO S1-T

CONSTRUCTION = INTW ..

C4-1T =INTERIOR-WALL AREA = 2775 NEXT-TO P-T

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M4T=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-T ..

$DAYLIGHT ROOM

E31WALL1=I-W LIKE EWALL1 ..

E31WALL2=I-W LIKE EWALL2 ..

E31WALL3=I-W LIKE EWALL3 ..

E31WALL4=E-W LIKE EWALL4 ..

E31WIND=WINDOW LIKE EWIND ..

E31FLR=I-W LIKE EFLR ..

E31CLG=I-W LIKE ECLG ..

$south-------------------------------------------

S5-T = SPACE LIKE S5-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(38,7,2.5) ..

SOUTH5-T =EXTERIOR-WALL HEIGHT = 9.0 WIDTH = 100

X=0 Y=0 Z=0 AZIMUTH = 180 ..

GL5-T =WINDOW HEIGHT=4.5 WIDTH = 100 ..

S12T =INTERIOR-WALL AREA=630 NEXT-TO S1-T

CONSTRUCTION = INTW ..

S14T =INTERIOR-WALL AREA=191 NEXT-TO S4-T

CONSTRUCTION = INTW ..

S15T =INTERIOR-WALL LIKE S12 NEXT-TO S2-T ..

C1-1T =INTERIOR-WALL AREA = 1275 NEXT-TO P-T

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M5T=INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO P-T ..

$DAYLIGHT ROOM------------------

S31WALL1=I-W LIKE SWALL1 ..

S31WALL2=I-W LIKE SWALL2 ..

S31WALL3=I-W LIKE SWALL3 ..

S31WALL4=E-W LIKE SWALL4 ..

S31WIND=WINDOW LIKE SWIND ..

S31FLR=I-W LIKE SFLR ..

S31CLG=I-W LIKE SCLG ..

$

$ BOTTOM FLOOR (NEXT TO BASEMENT)-----------------------------

$

P-B = SPACE LIKE P-M FLOOR-MULTIPLIER=1 ..

$core

S1-B = SPACE LIKE S1-M FLOOR-MULTIPLIER=1 ..

C5-1B =INTERIOR-WALL AREA = 11900 NEXT-TO P-B

CONSTRUCTION = CLNG-1 TILT=0.0 ..

F5-1B =INTERIOR-WALL AREA = 11900

CONSTRUCTION = FLOOR1 TILT=180.0

NEXT-TO S1-BAS ..

$west-------------------------------------------------------

S2-B = SPACE LIKE S2-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(7,93,2.5) ..

WEST-B =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=0.0 Y=200 Z=0 AZIMUTH = 270 ..

GL2-B =WINDOW HEIGHT=4.5 WIDTH = 200 ..

C2-1B =INTERIOR-WALL AREA = 2775 NEXT-TO P-B

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M2B=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO S1-BAS ..

M21B =INTERIOR-WALL AREA=1530 NEXT-TO S1-B

CONSTRUCTION = INTW ..

$DAYLIGHT ROOM---------------------------

MWWALL1=I-W LIKE WWALL1 ..

MWWALL2=I-W LIKE WWALL2 ..

MWWALL3=I-W LIKE WWALL3 ..

MWWALL4=E-W LIKE WWALL4 ..

MWWIND=WINDOW LIKE WWIND ..

MWFLR=I-W LIKE WFLR ..

MWCLG=I-W LIKE WCLG ..

$north---------------------------------------------------

S3-B = SPACE LIKE S3-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(47,193,2.5) ..

NORTH3-B =EXTERIOR-WALL HEIGHT = 9 WIDTH = 100

X=100 Y=200 Z=0 AZIMUTH = 0.0 ..

GL3-B =WINDOW HEIGHT=4.5 WIDTH = 100 ..

M31B =INTERIOR-WALL AREA=630 NEXT-TO S1-B

CONSTRUCTION = INTW ..

M34B =INTERIOR-WALL AREA=191 NEXT-TO S4-B

CONSTRUCTION = INTW ..

M32B =INTERIOR-WALL LIKE M34 NEXT-TO S2-B ..

C3-1B =INTERIOR-WALL AREA = 1275 NEXT-TO P-B

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M3B=INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO S1-BAS ..

$DAYLIGHT ROOM----------------------------

MNWALL1=I-W LIKE NWALL1 ..

MNWALL2=I-W LIKE NWALL2 ..

MNWALL3=I-W LIKE NWALL3 ..

MNWALL4=E-W LIKE NWALL4 ..

MNWIND=WINDOW LIKE NWIND ..

MNFLR=I-W LIKE NFLR ..

MNCLG=I-W LIKE NCLG ..

$east-----------------------------------------------------

S4-B = SPACE LIKE S4-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(88,93,2.5) ..

EAST-B =EXTERIOR-WALL HEIGHT = 9 WIDTH = 200

X=100 Y=0.0 Z=0 AZIMUTH = 90 ..

GL4-B =WINDOW HEIGHT=4.5 WIDTH = 200 ..

M41B =INTERIOR-WALL AREA=1530 NEXT-TO S1-B

CONSTRUCTION = INTW ..

C4-1B =INTERIOR-WALL AREA = 2775 NEXT-TO P-B

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M4B=INTERIOR-WALL AREA = 2775

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO S1-BAS ..

$DAYLIGHT ROOM

MEWALL1=I-W LIKE EWALL1 ..

MEWALL2=I-W LIKE EWALL2 ..

MEWALL3=I-W LIKE EWALL3 ..

MEWALL4=E-W LIKE EWALL4 ..

MEWIND=WINDOW LIKE EWIND ..

MEFLR=I-W LIKE EFLR ..

MECLG=I-W LIKE ECLG ..

$south-----------------------------------------------------

S5-B = SPACE LIKE S5-M FLOOR-MULTIPLIER=1

DAYLIGHTING=NO

LIGHT-REF-POINT1=(38,7,2.5) ..

SOUTH5-B =EXTERIOR-WALL HEIGHT = 9.0 WIDTH = 100

X=0 Y=0 Z=0 AZIMUTH = 180 ..

GL5-B =WINDOW HEIGHT=4.5 WIDTH = 100 ..

S12B =INTERIOR-WALL AREA=630 NEXT-TO S1-B

CONSTRUCTION = INTW ..

S14B =INTERIOR-WALL AREA=191 NEXT-TO S4-B

CONSTRUCTION = INTW ..

S15B =INTERIOR-WALL LIKE S12 NEXT-TO S2-B ..

C1-1B =INTERIOR-WALL AREA = 1275 NEXT-TO P-B

CONSTRUCTION = CLNG-1 TILT=0.0 ..

FL-M5B = INTERIOR-WALL AREA = 1275

CONSTRUCTION = FLOOR1 TILT= 180.0

NEXT-TO S1-BAS ..

$DAYLIGHT ROOM

MSWALL1=I-W LIKE SWALL1 ..

MSWALL2=I-W LIKE SWALL2 ..

MSWALL3=I-W LIKE SWALL3 ..

MSWALL4=E-W LIKE SWALL4 ..

MSWIND=WINDOW LIKE SWIND ..

MSFLR=I-W LIKE SFLR ..

MSCLG=I-W LIKE SCLG ..

$

$ GROUND FLOOR (ONE OF A KIND)

$

S1-BAS SPACE = AREA=20000 VOLUME=400000

ZONE-TYPE=UNCONDITIONED ..

WALL-1 UNDERGROUND-WALL AREA=12000

CONSTRUCTION=FLOOR1 U-EFFECTIVE=.02 ..

FLOOR-1 UNDERGROUND-FLOOR AREA=20000

CONSTRUCTION=FLOOR1

U-EFFECTIVE=.045 ..

END ..

COMPUTE LOADS ..

SAVE-FILES ..

$************************************************************************

INPUT SYSTEMS ..

$***** SYSTEM TITLE

TITLE LINE-1 *D. Keith Thesis Model*

LINE-2 *June 1997*

LINE-3 *31 story Office Building - Denver*

LINE-4 *Base Occ. / Base Ltg Rates *

LINE-5 *SYSTEM: VAV w/ Th = 72, Tc = 78, BOILER/HOT WATER *

..

$***** SYSTEM REPORTS

SYSTEMS-REPORT VERIFICATION = (SV-A)

SUMMARY = (SS-A, SS-H,SS-F) ..

$***** SYSTEM SCHEDULE

HTG-SCH = SCHEDULE THRU DEC 31

(WD) (1,8) (65) (9,16) (72) (17) (68.5) (18,24) (65)

(WEH) (1,24) (65) ..

CLG-SCH = SCHEDULE THRU DEC 31

(WD) (1,8) (85) (9,16) (76) (17) (80.5) (18,24) (85)

(WEH) (1,24) (85) ..

$***** ZONE DETAILS

Z-CTRL = ZONE-CONTROL

DESIGN-HEAT-T = 72

DESIGN-COOL-T = 76

HEAT-TEMP-SCH = HTG-SCH

COOL-TEMP-SCH = CLG-SCH

THERMOSTAT-TYPE = REVERSE-ACTION

THROTTLING-RANGE = 4

BASEBOARD-CTRL = THERMOSTATIC

..

Z-AIR = ZONE-AIR

$ A-CFM =

$ O-A-CFM =

..

$***** ZONE DEFINITION

S1-M = ZONE

ZONE-TYPE = CONDITIONED

ZONE-CONTROL = Z-CTRL

ZONE-AIR = Z-AIR

SIZING-OPTION = ADJUST-LOADS

$ SIZING-RATIO = ?

BASEBOARD-RATING = -99999999 ..

S2-M = ZONE LIKE S1-M $A-CFM = $ ..

S3-M = ZONE LIKE S1-M $A-CFM = $ ..

S4-M = ZONE LIKE S1-M $A-CFM = $ ..

S5-M = ZONE LIKE S1-M $A-CFM = $ ..

S1-T = ZONE LIKE S1-M $A-CFM = $ ..

S2-T= ZONE LIKE S1-M $A-CFM = $ ..

S3-T = ZONE LIKE S1-M $A-CFM = $ ..

S4-T = ZONE LIKE S1-M $A-CFM = $ ..

S5-T = ZONE LIKE S1-M $A-CFM = $ ..

S1-B = ZONE LIKE S1-M $A-CFM = $ ..

S2-B = ZONE LIKE S1-M $A-CFM = $ ..

S3-B = ZONE LIKE S1-M $A-CFM = $ ..

S4-B = ZONE LIKE S1-M $A-CFM = $ ..

S5-B = ZONE LIKE S1-M $A-CFM = $ ..

S1-BAS = ZONE ZONE-TYPE = UNCONDITIONED

D-H-T=10

D-C-T=120 ..

P-M = ZONE

ZONE-TYPE = PLENUM

S-O = ADJUST-LOADS

D-H-T = 50

D-C-T = 90 ..

P-T = ZONE LIKE P-M ..

P-B = ZONE LIKE P-M ..

$***** SYSTEM DETAILS

SYS-CTRL = SYSTEM-CONTROL

MIN-SUPPLY-T = 55

ECONO-LIMIT-T = 65 ..

$ BASEBOARD-SCH= KURMIT ..

SYS-AIR = SYSTEM-AIR

M-O-A=0.15 ..

$ RECOVERY-EFF=.5 ..

SYS-FANS = SYSTEM-FANS

FAN-CONTROL = INLET

$ RETURN-STATIC=2

$ RETURN-EFF=0.6

SUPPLY-STATIC= 6.5

SUPPLY-EFF = .7 ..

SYS-TERM = SYSTEM-TERMINAL

MIN-CFM-RATIO = 0.50

..

$***** SYSTEM DEFINITION

BLDG-SYS-M = SYSTEM $ MIDDLE FLOORS, 29 CT

SYSTEM-TYPE = VAVS

SYSTEM-CONTROL = SYS-CTRL

SYSTEM-AIR = SYS-AIR

SYSTEM-FANS = SYS-FANS

SYSTEM-TERMINAL = SYS-TERM

BASEBOARD-SOURCE = HOT-WATER

RETURN-AIR-PATH= PLENUM-ZONES

PLENUM-NAMES = (P-M)

ZONE-NAMES = (S1-M, S2-M, S3-M, S4-M, S5-M, P-M)

..

BLDG-SYS-B = SYSTEM $ BASE FLOOR, 1 CT

SYSTEM-TYPE = VAVS

SYSTEM-CONTROL = SYS-CTRL

SYSTEM-AIR = SYS-AIR

SYSTEM-FANS = SYS-FANS

SYSTEM-TERMINAL = SYS-TERM

BASEBOARD-SOURCE=HOT-WATER

RETURN-AIR-PATH= PLENUM-ZONES

PLENUM-NAMES = (P-B)

ZONE-NAMES = (S1-B, S2-B, S3-B, S4-B, S5-B, P-B,S1-BAS)

..

BLDG-SYS-T = SYSTEM $ TOP FLOOR, 1 CT

SYSTEM-TYPE = VAVS

SYSTEM-CONTROL = SYS-CTRL

SYSTEM-AIR = SYS-AIR

SYSTEM-FANS = SYS-FANS

SYSTEM-TERMINAL = SYS-TERM

BASEBOARD-SOURCE=HOT-WATER

RETURN-AIR-PATH= PLENUM-ZONES

PLENUM-NAMES = (P-T)

ZONE-NAMES = (S1-T, S2-T, S3-T, S4-T, S5-T, P-T)

..

END ..

COMPUTE SYSTEMS ..

INPUT PLANT ..

TITLE LINE-1 *D. Keith Thesis Model*

LINE-2 *June 1997*

LINE-3 *31 story Office Building - Denver*

LINE-4 *Base Occ. / Base Ltg Rates *

LINE-5 *Plant as HERM-REC-Chiller* ..

ABORT ERRORS ..

DIAGNOSTIC WARNINGS ..

PLANT-REPORT VERIFICATION = (PV-A)

SUMMARY = (PS-A,PS-B,BEPS) ..

PERF-DATA = CURVE-FIT

TYPE = QUADRATIC

DATA = (1,1) (0.8,0.800)(0.6,0.610)(0.4,0.442)(0.2,0.340) ..

CHLR-1 = PLANT-EQUIPMENT

TYPE = HERM-REC-CHLR

SIZE = -999

I-N = 1

M-N-A = 1 ..

PART-LOAD-RATIO

TYPE = HERM-REC-CHLR E-I-R = 0.324 MIN-RATIO = 0.2 ..

EQUIPMENT-QUAD

HERM-REC-EIR-FPLR = PERF-DATA ..

PLANT-PARAMETERS

BOILER-FUEL = NATURAL-GAS

HERM-REC-COND-TYPE = AIR HW-BOILER-HIR = 1.43 ..

BOILER-1 = PLANT-EQUIPMENT

TYPE = HW-BOILER

SIZE = -999

I-N = 1

M-N-A = 1 ..

END ..

COMPUTE PLANT ..

$ this is the basic ECONOMICS file with everything in it

INPUT ECONOMICS ..

TITLE LINE-1 *D. Keith Thesis Model*

LINE-2 *June 1997*

LINE-3 *31 story Office Building - Denver*

LINE-4 *Base Occ. / Base Ltg Rates *

LINE-5 *ECONOMICS RUN* ..

ECONOMICS-REPORT SUMMARY = (ALL-SUMMARY)

VERIFICATION = (EV-A,EV-B) ..

ELEC-SCH = SCHEDULE THRU DEC 31 (WD) ON-1

(WEH) OFF-1 ..

ON-1 = DAY-CHARGE-SCH (1,24) (PEAK) ..

OFF-1 = DAY-CHARGE-SCH (1,24) (PEAK) ..

$ ELECTRICAL

ENERGY-COST

RESOURCE = ELECTRICITY

UNIT = 3413

ASSIGN-SCHEDULE= ELEC-SCH

ASSIGN-CHARGE = (PEAK) ..

PEAK = CHARGE-ASSIGNMENT

RESOURCE = ELECTRICITY

TYPE=ENERGY

$ UNIFORM-CHARGE = 0.05538

UNIFORM-CHARGE = 0.01787

TYPE=DEMAND

$ UNIFORM-CHARGE = 11.78

UNIFORM-CHARGE = 12.55 ..

$ OFFP = CHARGE-ASSIGNMENT

$ RESOURCE = ELECTRICITY

$ TYPE=ENERGY

$ UNIFORM-CHARGE = 0.03629 ..

$ HOT WATER

ENERGY-COST

RESOURCE = STEAM

UNIT = 1000000

UNIFORM-COST = 4.15 ..

$ CHILLED WATER

ENERGY-COST

RESOURCE = CHILLED-WATER

UNIT = 12000

UNIFORM-COST = 0.144 ..

$ NATURAL GAS

ENERGY-COST

RESOURCE = NATURAL-GAS

UNIT = 100000

UNIFORM-COST=1.0 ..

END ..

COMPUTE ECONOMICS ..

STOP ..